home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
C64
/
U-Utilities
/
(c)u2.d64
/
change title.c
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2007-02-04
|
1KB
|
44 lines
1 OPEN15,8,15:GOSUB19
2 PRINT#15,"I0":GOSUB19
3 OPEN2,8,2,"#":GOSUB19
4 DIMA$(15):PRINT#15,"U1:2,0";18;0:GOSUB19
5 PRINT#15,"B-P:2,144":GOSUB19
6 FORI=0TO15:GET#2,A$(I):GOSUB19:NEXT
7 PRINT"[147]OLD TITLE:":FORI=0TO15:PRINT"";A$(I);"[146]";:NEXT
8 PRINT:PRINT"DO YOU WISH TO CHANGE IT ? ";
9 GETA$:IFA$<>"Y"ANDA$<>"N"THEN9
10 PRINTA$:IFA$="N"THEN18
11 INPUT"NEW TITLE ";A$
12 IFLEN(A$)>16THENA$=LEFT$(A$,16)
13 IFLEN(A$)<16THENA$=A$+" ":GOTO13
14 PRINT#15,"B-P:2,144":GOSUB19
15 FORI=1TO16:PRINT#2,MID$(A$,I,1);:GOSUB19:NEXT
16 PRINT#15,"U2:2,0,18,0":GOSUB19
17 PRINT#15,"I0":GOSUB19
18 FORI=1TO15:CLOSEI:NEXT:END
19 INPUT#15,EN,EM$,ET,ES:IFEN=0THENRETURN
20 PRINT:PRINTEN;EM$;ET;ES:GOTO18
21 REM: * * :
22 REM: * CHANGE TITLE * :
23 REM: * * :
24 REM: * BY * :
25 REM: * * :
26 REM: * BOB SWIFT * :
27 REM: * * :
28 REM: **************** :
29 REM: :
30 REM: THIS PROGRAM, WHEN 'RUN', :
31 REM: WILL ALLOW YOU TO CHANGE :
32 REM: THE TITLE OF THE DISK IN :
33 REM: YOUR VIC-1541 DRIVE. THE :
34 REM: PROGRAM FIRST DISPLAYS THE :
35 REM: PRESENT TITLE, AND THEN :
36 REM: ASKS IF YOU WISH TO CHANGE :
37 REM: IT. IF YOU SAY 'Y' THE :
38 REM: PROGRAM THEN ASKS YOU FOR :
39 REM: THE NEW TITLE, AND CHANGES :
40 REM: IT ON THE DISK. THIS PROGRAM :
41 REM: WILL NOT AFFECT ANYTHING :
42 REM: ELSE ON THE DISK. :
43 REM: :